0    -.OB "Z80.OBJ,P,W"
1    -;
2    -; Z80 EIN- UND AUSSCHALTEN  STK  10/96
3    -;
4    -          .BA 10000
5    -;
6    -          .EQ PRIMM=$FF7D;              NACHFOLGENDEN TEXT AUSGEBEN
7    -          .EQ CPU8502=$FFE0;            8502 REAKTIVIEREN
8    -          .EQ Z80START=$FFEE;           STARTADRESSE Z80
9    -          .EQ CR=$FF00   ;              KONFIGURATIONS-REGISTER
10   -          .EQ MCR=$D505  ;              MODUS-KONF.-REGISTER
11   -;
12   -; TEXT AUSGEBEN
13   -;
14   -          JSR PRIMM
15   -          .TX "[ÃÌÒ][ÄÏ×Î]      PER Z80-LDIR-ANWEISUNG WIRD"
16   -          .BY 13
17   -          .TX "      DIE FUNKTIONSTASTENBELEGUNG"
18   -          .BY 13
19   -          .TX "      AB $1000 NACH $1300 KOPIERT"
20   -          .BY 13,13
21   -          .TX "      THOMAS KLEIN    STK - 10/96"
22   -          .BY 13,0
23   -;
24   -; 'JP Z80CODE' NACH Z80START
25   -;
26   -          LDA #$C3
27   -          STA Z80START
28   -          LDA #<(Z80CODE)
29   -          STA Z80START+1
30   -          LDA #>(Z80CODE)
31   -          STA Z80START+2
32   -;
33   -; Z80 EINSCHALTEN
34   -;
35   -          SEI
36   -          LDA #$3E       ;              SPEICHERKONFIGURATION
37   -          STA CR
38   -          LDA #$B0       ;              Z80 EIN
39   -          STA MCR
40   -          NOP            ;              WARTEN
41   -;
42   -; PROGRAMMENDE
43   -;
44   -          CLI
45   -          RTS
46   -;
47   -; Z80-CODE: $1000-$10FF NACH $1300
48   -;
49   -Z80CODE   .BY $3E,$3F    ;              LD A,$3F      KONFIGURATION
50   -          .BY $32,$00,$FF;              LD ($FF00),A  NACH $FF00
51   -          .BY $21,$00,$10;              LD HL,$1000   STARTADR.
52   -          .BY $11,$00,$13;              LD DE,$1300   ZIELADR.
53   -          .BY $01,$00,$01;              LD BC,$0100   LAENGE
54   -          .BY $ED,$B0    ;              LDIR          KOPIEREN
55   -          .BY $C3,<(CPU8502),>(CPU8502);JP CPU8502
56   -;
57   -.EN