0     -.OB "ASS-GRAFIK 128,P,W"
1    -; ASS-GRAFIK  STK  02.03.96
2    -;
3    -          .BA $1300
4    -;
5    -          .EQ GRAPHIC=$6B6C;    GRAFIKMODUS WAEHLEN
6    -          .EQ GRAPHICCLR=$A022; GRAFIKSPEICHER FREIGEBEN
7    -          .EQ GCLEAR=$6B30;     GRAFIK LOESCHEN
8    -          .EQ GCOLOR=$6A5C;     GRAFIKFARBEN SETZEN
9    -          .EQ DRAW=$AF72 ;      LINIE ZEICHNEN
10   -          .EQ BOX=$62D7  ;      RECHTECK ZEICHNEN
11   -          .EQ PAINT=$61BD;      BEREICH FUELLEN
12   -          .EQ CIRCLE=$66DF;     KREISBOGEN ZEICHNEN
13   -          .EQ CHAR=$68DB ;      ZEICHEN AUSGEBEN
14   -;
15   -          .EQ GETIN=$FFE4;      TASTATUR ABFRAGEN
16   -;
17   -START     LDA #$00       ;ROMS EIN
18   -          STA $FF00      ;(=BANK15)
19   -;
20   -;FARBEN SETZEN, GRAFIK EIN U. LOESCHEN
21   -          LDA #12
22   -          STA $D020      ;RAHMEN
23   -          STA $D021      ;HINTERGRUND
24   -          LDA #0
25   -          STA $86        ;VORDERGRUND
26   -          LDA #1
27   -          STA $84        ;MULTI1
28   -          LDA #6
29   -          STA $85        ;MULTI2
30   -          JSR GCOLOR     ;FARBEN SETZEN
31   -          LDX #3
32   -          JSR GRAPHIC    ;MULTICOLOR EIN
33   -          JSR GCLEAR     ;GRAFIK LOESCHEN
34   -;
35   -;TEXT AUSGEBEN
36   -          LDA #2
37   -          STA $83        ;FARBE=MULTI1
38   -          LDA #0
39   -          STA $113D      ;NICHT REVERS
40   -          LDA #$D8
41   -          STA $1168      ;ZEICHENSATZ 2
42   -          LDX #0
43   -          LDY #2         ;STARTSPALTE
44   -TEXTLOOP  LDA TEXTTAB,X
45   -          BEQ RAHMEN     ;ENDE MIT 0
46   -          STX MERKX
47   -          LDX #0         ;ZEILE
48   -          JSR CHAR       ;ZEICHEN AUSGEBEN
49   -          LDX MERKX
50   -          INX
51   -          INY
52   -          BNE TEXTLOOP   ;UNBEDINGTER SPRUNG
53   -;
54   -;RAHMEN ZEICHNEN
55   -RAHMEN    LDX #1
56   -          STX $83        ;FARBE=VORDERGRUND
57   -          STX $116B      ;DOPPELTE PUNKTBREITE
58   -          DEX            ;KOORDINATENHIGHBYTES=0
59   -          STX $1151
60   -          STX $1153
61   -          STX $115D
62   -          STX $115F
63   -          STX $1154      ;ROTATIONSWINKEL=0
64   -          STX $1155
65   -          STX $1150      ;X1
66   -          LDX #8
67   -          STX $1152      ;Y1
68   -          LDX #158
69   -          STX $115C      ;X2
70   -          LDX #199
71   -          STX $115E      ;Y2
72   -          LDX #0         ;NICHT AUSFUELLEN
73   -          JSR BOX        ;RECHTECK ZEICHNEN
74   -;
75   -;DIAGONALEN ZEICHNEN
76   -          LDX #0         ;EINFACHE PUNKTBREITE
77   -          STX $116B      ;ENDPUNKT(HIGHBYTES=0 V. BOX):
78   -          INX
79   -          STX $1135      ;X2
80   -          LDA #8
81   -          STA $1137      ;Y2
82   -          JSR DRAW       ;ANFANGSPUNKT: X2,Y2 VON BOX
83   -          LDA #159
84   -          STA $1131      ;X1
85   -          LDA #1
86   -          STA $1135      ;X2
87   -          LDA #199
88   -          STA $1137      ;Y2
89   -          JSR DRAW
90   -;
91   -;KREISE MIT UNTERSCHIEDLICHEN RADIEN
92   -          LDA #2
93   -          STA $83        ;FARBE=MULTI1
94   -          LDA #80        ;XMITTE
95   -          STA $1150
96   -          LDA #104       ;YMITTE
97   -          STA $1152
98   -          LDA #0         ;STARTWINKEL
99   -          STA $115C
100  -          LDA #<(360)
101  -          STA $115E      ;ENDWINKEL
102  -          LDA #>(360)
103  -          STA $115F      ;ANDERE HIGHBYTES NOCH 0 V. BOX
104  -          LDA #10        ;STARTRADIUS
105  -CIRCLELOOP PHA           ;RADIUS MERKEN
106  -          STA $1156      ;YRADIUS
107  -          LSR            ;DURCH 2
108  -          STA $1154      ;XRADIUS
109  -          LDA #0         ;ROTATIONSWINKEL=0
110  -          TAY
111  -          JSR CIRCLE     ;KREIS ZEICHNEN
112  -          PLA            ;RADIUS ZURUECK
113  -          CLC
114  -          ADC #10        ;RADIUS+10
115  -          CMP #90        ;FALLS<70
116  -          BCC CIRCLELOOP ;NAECHSTER KREIS
117  -;
118  -;ROTIERENDE RECHTECKE
119  -          LDX #3
120  -          STX $83        ;MULTI2
121  -          LDA #0         ;HIGHBYTES=0
122  -          STA $1151
123  -          STA $1153
124  -          STA $115D
125  -          STA $115F
126  -          STA $1155
127  -RAHMENLOOP PHA
128  -          STA $1154      ;ROTATIONSWINKEL
129  -          LDX #50
130  -          STX $1150      ;X1
131  -          LDX #44
132  -          STX $1152      ;Y1
133  -          LDX #110
134  -          STX $115C      ;X2
135  -          LDX #164
136  -          STX $115E      ;Y2
137  -          LDX #0         ;NICHT AUSFUELLEN
138  -          JSR BOX        ;RECHTECK ZEICHNEN
139  -          PLA
140  -          CLC
141  -          ADC #15        ;ROTATIONSWINKEL+15
142  -          CMP #180       ;<180:NAECHSTES RECHTECK
143  -          BCC RAHMENLOOP
144  -;
145  -;BEREICHE AUSFUELLEN
146  -          LDA #7
147  -          STA $84        ;MULTI2=GELB
148  -          JSR GCOLOR     ;FARBEN SETZEN
149  -          LDA #2         ;FARBE=MULTI2
150  -          STA $83
151  -          LDA #2
152  -          STA $1131      ;X
153  -          LDA #100
154  -          STA $1133      ;Y
155  -          LDX #1         ;MODUS
156  -          JSR PAINT      ;AUSFUELLEN
157  -          LDA #157
158  -          STA $1131      ;X
159  -          LDA #100
160  -          STA $1133      ;Y
161  -          LDX #1         ;MODUS
162  -          JSR PAINT      ;AUSFUELLEN
163  -;
164  -;NACH TASTE: GRAFIK AUS
165  -TASTE     JSR GETIN      ;TASTATUR ABFRAGEN
166  -          BEQ TASTE      ;KEINE TASTE: ZURUECK
167  -          LDX #0
168  -          JSR GRAPHIC    ;GRAPHIC 0
169  -          JMP GRAPHICCLR ;GRAPHIC CLR
170  -;
171  -TEXTTAB   .TX "Ã128-ÇRAFIK IN ÁSSEMBLER  '96 BY ÓÔË";UEBERSCHRIFT
172  -          .BY 0
173  -MERKX     .BY 0          ;ZWISCHENSPEICHER FUER TEXTAUSGABE
174  -.EN