0     -.OB "LIGHTBIKES 128,P,W"
1    -; LIGHTBIKES 128  STK  7/88, 1/91, 3/96
2    -;
3    -          .BA $1300
4    -;
5    -          .EQ GRAPHIC=$6B6C;      GRAFIK EIN
6    -          .EQ GCLEAR=$6B30;       GRAFIK LOESCHEN
7    -          .EQ DOT=$AF75  ;        PUNKT SETZEN
8    -          .EQ RDOT=$9C49 ;        PUNKT TESTEN
9    -          .EQ BOX=$62D7  ;        RECHTECK ZEICHNEN
10   -;
11   -          .EQ X0=$FB     ;        X-KOORDINATE SPIELER 1
12   -          .EQ X1=$FC     ;        X-KOORDINATE SPIELER 2
13   -          .EQ Y0=$FD     ;        Y-KOORDINATE SPIELER 1
14   -          .EQ Y1=$FE     ;        Y-KOORDINATE SPIELER 2
15   -          .EQ R0=$B6     ;        RICHTUNG SPIELER 1
16   -          .EQ R1=$B7     ;        RICHTUNG SPIELER 2
17   -          .EQ PNT=$D1    ;        CURSORZEILE IM BILDSCHIRMSPEICHER
18   -          .EQ PNTR=$D3   ;        CURSORSPALTE
19   -          .EQ SPEED=6    ;        WERT FUER VERZOEGERUNGSSCHLEIFE
20   -;
21   -; INITIALISIERUNGEN U. BILDSCHIRMAUFBAU
22   -;
23   -START     LDA #0         ;
24   -          STA $D021      ;        HINTERGRUNDFARBE
25   -          STA $116B      ;        EINFACHE PUNKTBREITE
26   -          LDX #$2E       ;        KOORDINATENSPEICHER LOESCHEN
27   -CLRKOOR   STA $1131,X    ;        (INSBESONDERE HIGHBYTES)
28   -          DEX
29   -          BPL CLRKOOR
30   -WAIT      LDA 56321      ;        AUF FEUERKNOPF WARTEN
31   -          AND 56320
32   -          AND #16
33   -          BNE WAIT
34   -          LDX #3         ;        MULTICOLOR-FARBE 2 WAEHLEN
35   -          STX $83
36   -          JSR GRAPHIC    ;        MULTICOLORMODUS EIN
37   -          JSR GCLEAR     ;        GRAFIK LOESCHEN
38   -          LDA #159       ;        X2
39   -          STA $115C
40   -          LDA #199       ;        Y2
41   -          STA $115E
42   -          LDX #0         ;        NICHT AUSFUELLEN
43   -          JSR BOX        ;        RAHMEN ZEICHNEN
44   -;
45   -; SPIELRUNDEN VORBEREITEN
46   -;
47   -          LDA #100       ;        STARTPOSITIONEN SETZEN
48   -          STA Y0
49   -          STA Y1
50   -          STA X1
51   -          LDA #60
52   -          STA X0
53   -          LDA #14        ;        STARTRICHTUNGEN
54   -          STA R0
55   -          STA R1
56   -;
57   -; SPIELSCHLEIFE
58   -;
59   -S11       LDX #2         ;        SPIELER 1 ABFRAGEN
60   -          JSR JOY
61   -          BNE START      ;        KOLLISION: SPIELSCHLEIFE VERLASSEN
62   -          LDX #3         ;        SPIELER 2 ABFRAGEN
63   -          JSR JOY
64   -          BNE START      ;        KOLLISION: SPIELSCHLEIFE VERLASSEN
65   -          LDX #SPEED     ;        VERZOEGERUNGSSCHLEIFE
66   -          TAY            ;        Y=0
67   -S12       DEY
68   -          BNE S12
69   -          DEX
70   -          BNE S12
71   -          BEQ S11        ;        ZUM ANFANG DER SPIELSCHLEIFE
72   -;
73   -; JOYSTICK VON SPIELER X-1 ABFRAGEN
74   -;
75   -JOY       STX $83        ;        FARBE WAEHLEN
76   -          LDA $84-2,X    ;        RAHMEN IN SPIELERFARBE
77   -          STA $D020
78   -          LDA R0-2,X     ;        AKTUELLE RICHTUNG SPEICHERN
79   -          PHA
80   -          LDA 56320-2,X  ;        JOYSTICK LESEN
81   -          AND #15
82   -          CMP #15
83   -          BEQ S3         ;        NEUE RICHTUNG?
84   -SB        STA R0-2,X     ;        JA: SPEICHERN
85   -S3        LDA R0-2,X     ;        KOORDINATEN ENTSPRECHEND
86   -          CLV            ;        RICHTUNG AENDERN
87   -          CMP #14
88   -          BNE S4
89   -          DEC Y0-2,X
90   -          BVC S8
91   -S4        CMP #13
92   -          BNE S5
93   -          INC Y0-2,X
94   -          BVC S8
95   -S5        CMP #11
96   -          BNE S6
97   -          DEC X0-2,X
98   -          BVC S8
99   -S6        CMP #7
100  -          BEQ SA
101  -          PLA
102  -          PHA
103  -          BNE SB
104  -SA        INC X0-2,X
105  -S8        PLA
106  -          LDA X0-2,X     ;        KOORDINATEN FUER DOT/RDOT
107  -          STA $1131
108  -          LDA Y0-2,X
109  -          STA $1133
110  -          JSR RDOT       ;        PUNKT TESTEN
111  -          CMP #0
112  -          PHP            ;        VERGLEICHSERGEBNIS SPEICHERN
113  -          JSR DOT        ;        PUNKT SETZEN
114  -          PLP            ;        VERGLEICHSERGEBNIS LADEN
115  -          RTS
116  -.EN